2. Fórumok
  3. OS, alkalmazások
  4. Microsoft Excel topic
  5. (kiemelt téma)
  • Téma összefoglaló
    Utoljára frissítve: 2023-11-13 08:31

    IT café

    A Microsoft Excel topic célja segítséget kérni és nyújtani Excellel kapcsolatos problémákra.
    Kérdés felvetése előtt olvasd el, ha még nem tetted.

Új hozzászólás Aktív témák

  • #37917 Mutt aktív tag szricsi_0917 #37915
    Új Válasz #37917
    Új hozzászólás
    Összes hozzászólása itt Válaszok az összes hozzászólására itt Válaszok erre a hozzászólásra
    Privát üzenet küldése

    Mutt

    aktív tag

    válasz szricsi_0917 #37915 üzenetére

    Szia,

    Ha a hónap napjai dátumok a fejlécben, akkor a HÉT.NAPJA függvény tud segíteni a hétvégéket megtalálni, amit a SZORZATÖSSZEG vagy a SZUM függvénnyel lehet használni.

    A fejléc a B1:AF1 tartományban van, a ledolgozott idő a B2:AF2 tartományban.
    =SZORZATÖSSZEG(--(HÉT.NAPJA($B$1:$AF$1;11)>5)*B2:AF2)

    A fenti függvény elhasal, ha szöveg (akár csak egy szóköz) is van az alsó sorban, viszont a következő tömbfüggvény ekkor sem hasal el:
    =SZUM(--(HÉT.NAPJA($B$1:$AF$1;11)>5)*(HA(SZÁM(B2:AF2);B2:AF2;0)))

    Ha az első sor szöveg (vagyis nem 2018.04.01. van ott, hanem "01.V"), akkor pedig "V" és "Szo" szövegre kell keresni a SZUMHA függvénnyel:

    =SZUMHA($B$1:$AF$1;"*V";B2:AF2)+SZUMHA($B$1:$AF$1;"*Szo";B2:AF2)

    Rövidebben a SZUMHATÖBB-el:
    =SZUM(SZUMHATÖBB(B2:AF2;$B$1:$AF$1;{"*V"\"*Szo"}))

    Mindegyik megoldás hátránya, hogy mindig 31 napot nézel és előfordulhat hogy a következő hónap elseje (pl. július 1) is hétvégére esik, ha csak az adott hónap hétvégéi számítanak, akkor ez a tömbfüggvény jó lesz:
    =SZUM(--(HÉT.NAPJA($B$1:$AF$1;11)>5)*(HA(HÓNAP($B$1:$AF$1)=HÓNAP($B$1);B2:AF2;0)))

    üdv

    [ Szerkesztve ]

    A tanácsaimat ingyen adom. Ha nem tetszik, akkor kérlek ne kritizáld! / https://github.com/viszi/codes/tree/master/Excel

Új hozzászólás Aktív témák